Aprenda 25 cálculos com hora no Excel com vídeo-aula, fórmulas pronta e download gratuito da planilha de exemplo.
Vídeo-aula Cálculos com Hora
Download Planilha Cálculos de Hora Excel
Para realizar o download da planilha com cálculos de Tempo no Excel clique no botão abaixo e preencha o formulário.
Converter Texto em Tempo no Excel
Para converter um texto em hora no Excel pode ser feito de duas formas.
A primeira forma é multiplicando o valor por 1, por exemplo digamos que em A1 está 15:24:35, temos então:
=A1*1
Com isso o valor é convertido automaticamnete para hora. Outra forma é utilizar a função VALOR.TEMPO.
A função VALOR.TEMPO converte texto em tempo também, e a aplicação dela é:
=VALOR.TEMPO(A1)
Formtação de Tempo com Texto
O Excel permite também realizar formatação de texto de modo que a hora faça parte de um texto.
Como exemplo temos na célula G8 o valor de 09:50 e queremos que este valor fique com o texto: A entrega deve ser feita às 08:50
Para aplicar a formatação de texto basta clicar com o botão direito em uma célula e clicar em Formatar Texto e clique em Personalizado.
Neste campo digite: “A entrega deve ser feita às “hh:mm”
Com isso temos na célula ainda o valor de 08:50, mas visualmente fica com o texto A entrega deve ser feita às 08:50
Colocar Hora no Texto no Excel
Para colocarmos um texto com hora no Excel podemos utilizar a função TEXTO.
A função texto tem por finalidade formatar textos de modo personalizado.
Para isso usamos a fórmula: =“A previsão de aterrissagem é às “&TEXTO(B8;”HH:MM”)
Veja que na fórmula temos o texto A previsão de aterrissagem é às 08:50.
Extrair Hora no Excel
Para extrair hora no Excel nós utilizamos a função HORA.
A utilização desta função é bastante prática, basta passar a célula com o valor de hora. Digamos que o valor é 08:50:40.
=HORA(B8)
Com isso temos o retorno da hora, que é 08.
Extrair Minuto no Excel
Para extrair minuto no Excel nós utilizamos a função MINUTO.
A utilização desta função é bastante prática, basta passar a célula com o valor de minuto. Digamos que o valor é 08:50:40.
=MINUTO(B8)
Com isso temos o retorno da hora, que é 50.
Extrair Segundo no Excel
Para extrair segundos no Excel nós utilizamos a função SEGUNDO.
A utilização desta função é bastante prática, basta passar a célula com o valor de minuto. Digamos que o valor é 08:50:40.
=SEGUNDO(B8)
Com isso temos o retorno da hora, que é 40.
Fórmula com Hora Atual no Excel
Para calcular a hora atual no Excel pode usar a função =AGORA().
A função agora não precisa de parâmetro, a aplicação dela é =AGORA() e o retorno dela é 10:04:50, ou seja o tempo atual do Windows.
Para atualizar a hora na célula do Excel basta clicar F9 e a hora é atualizada imediatamente.
Atalho para Aplicar Hora Fixa no Excel
Podemos aplicar uma hora fixa no Excel em uma fórmula.
Para isso basta selecionar uma célula e pressionar o atalho CTRL+:.
Com isso você terá a aplicação do tempo em uma célula do Excel, por exemplo 15:06:00.
Criar um Campo de Tempo no Excel
Para criar um campo de hora no Excel podemos unir campos de números de célula para montar uma fórmula.
Digamos que nas células I8 tenhamos 08, na J8 temos 50 e na K8 temos 40.
Para unir estes números e converter para um formato de hora temos: =TEMPO(I8;J8;K8)
Com isso temos 08:50:40, uma hora pronta e formatada.
Como Adicionar Tempo no Excel
Para adicionar tempo no Excel podemos aplicar o cálculo utilizando +.
No nosso exemplo temos: =C8+”05:00″
Considerando que o valor é 09:37:59 somando com 05:00 teremos então o valor de 14:37:59.
Como Reduzir Tempo no Excel
Para reduzir horas no Excel basta utilizar a o operador -.
No nosso exemplo temos: =B8-“07:24”
Digamos que o valor é 08:50:40 e queremos reduzir 07:24 com isso temos a diferença de 01:26:40.
Cálculos de Tempo no Excel Passando de 24:00
Para realizar cálculos com horas no Excel passando de 24:00 podemos aplicar uma formação personalizada.
No nosso exemplo temos que na célula C8 temos 09:37:49 e somamos 20:00. Aplicando =C8+”20:00″
Para realizar este cálculo clicamos com o botão direito em Formatar células–Hora e selecione 37:30:55.
Como resultado temos 29:37:59.
Cálculo de Tempo Decorrido Excel
Para realizar o cálculo de tempo decorrido no Excel podemos calcular o valor de uma célula menos de outra célula.
Por exemplo C8-B8. Aonde temos em Hora final (C8) o valor de 09:37:59 e na célula de Hora inicial (B8) o valor de 08:50:40.
Com isso temos a diferença de =C8-B8, e como resultado temos 00:47.
Cálculo de Horas Negativas no Excel
Se tentarmos aplicar o cálculo direto de tempo decorrido temos um erro no Excel, exibindo então ###############.
Para resolver este problema podemos usar a seguinte função:
=SE(C15<B15;”-“&TEXTO(ABS(C15-B15);”HH:MM”);C15-B15)
Em C15 temos o valor de 12:33:15 e na célula B15 temos o valor 12:52:47.
Como resultado temos -00:19, porém este valor de hora ficará como texto.
Converter Horas em Decimais no Excel
Para converter tempo no Excel em decimais podemos aplicar a seguinte função.
Digamos que em R8 temos o valor de 00:47 com isso multiplicamos pelo valor 24.
Com isso multiplicamos um campo de hora pelo valor de 24: =R8*24.
Como resultado temos 0,79, ou seja 79% de uma hora.
Cálculo de Tempo Negativo no Excel
Para calcular hora negativa no Excel podemos aplicar o cálculo da diferença de tempo e multiplicar por 24.
No nosso exemplo usamos a fórmula: =(C8-B8)*24.
Na célula C15 temos o valor de 12:33:15 e na célula B15 o valor de 12:52:47.
Quando aplicamos a diferença de hora final menos hora inicial e multiplicamos por 24 temos o resultado de -0,33.
O valor de -0,33 é o mesmo de -00:19. Ou seja 33% de uma hora.
Converter Hora em Minutos Decimais no Excel
Para converter hora em minutos decimais no Excel podemos aplicar o seguinte cálculo:
=(C9-B9)*24*60
Com isso temos o cálculo de quantos minutos, de modo decimal, temos entre duas horas.
Digamos que na célula é C9 temos o valor de 10:03:30 e na B9 temos o valor de 08:54:30.
Como resultado temos o valor de 68,99 minutos.
Converter Tempo em Segundos Decimais no Excel
Para converter hora em minutos decimais no Excel podemos aplicar o seguinte cálculo:
=(C8-B8)*24*60*60
Com isso temos o cálculo de quantos minutos, de modo decimal, temos entre duas horas.
Digamos que na célula é C8 temos o valor de 09:37:59 e na B8 temos o valor de 08:50:40.
Como resultado temos o valor de 2840 segundos.
Calcular Valor Total por Hora no Excel
Para calcular o valor total de hora no Excel podemos fazer da seguinte forma.
Digamos que o valor hora na célula X8 é R$ 82,00, no célula c8 temos 09:37:59 e na célula B8 temos 08:50:40.
Para realizar o cálculo de valor total a se pagar sabendo que o valor da hora é 82,00 temos então a seguinte fórmula:
=(C8-B8)*24*X8
Com isso temos o valor total de R$ 64,68, pois é uma fração de hora a diferença, que é de 00:47.
Cálculo de Tempo Aleatório no Excel
Para realizar o cálculo de hora aleatória podemos usar uma fórmula de matriz dinâmica.
Com isso aplicamos a fórmula =CLASSIFICAR(MATRIZALEATÓRIA(24;;Z6)) considerando em Z6 o valor de 08:00.
A função matrizaleatória realiza a criação de uma matriz de valores, nela estamos passando 24 como a quantidade de linhas que desejamos colocar na nossa lista.
E no campo mínimo da matriz colocamos 08:00.
então como resultado temos uma lista aleatória começando de 08:00 e usando a função CLASSIFICAR, classificamos os valores gerados aleatoriamente no Excel.
Cálculo de Tempo Aleatório Entre Dois Valores
Neste exemplo estamos criando uma lista de horas aleatórias entre um determinado período.
Digamos que a hora inicial é 08:00 e a final é 17:00 nós temos o seguinte cálculo:
=TEMPO(ALEATÓRIOENTRE(HORA($AA$5);HORA($AA$6));
ALEATÓRIOENTRE(0;59);
ALEATÓRIOENTRE(0;59))
Veja que no exemplo abaixo estamos usando a função de aleatórioentre utilizada nos campos de hora, minuto e segundo na função TEMPO.
Como resultado temos uma lista entre às 08:00 e às 17:00.
Criar Lista Sequencial de Tempo no Excel
Para criar uma lista sequencial de horas no Excel podemos utilizar a seguinte fórmula:
=TEMPO(SEQUÊNCIA(HORA(AB6)-HORA(AB5)+1;;AB5*24);0;0)
Veja que temos o uso da função TEMPO e passamos nela a função sequência, aonde passamos uma diferença das horas entre a hora final e inicial e somamos 1.
No valor inicial da lista passamos a hora inicial multiplicado por 24 para que funcione adequadamente a hora inicial.
Criar Lista de Tempo de 30 Minutos em 30 Minutos
Neste exemplo criamos uma fórmula para gerar uma lista automática de horas de 30 em 30 minutos.
Para realizar esta tarefa usamos a fórmula =TEMPO(HORA(AC5);SEQUÊNCIA((HORA(AC6)-HORA(AC5))*2+1;;0;30);0).
Veja que na função passamos novamente para a função TEMPO a hora inicial pelo campo HORA e no campo de minutos usamos a função SEQUÊNCIA para os minutos e geramos a diferença de horas entre a final e a inicial e multiplicamos por 2 +1.
Com isso geramos uma lista com duas vezes a quantidade de horas entre a inicial e a final, isso se deve ao fato de termos em cada hora 30 minutos.
Por fim, passamos no parâmetro [final] da função SEQUÊNCIA a quantidade que desejamos que seja feito o passo, ou seja, acrescentado de 30 em 30 minutos.l
Download Planilha Cálculos de Hora Excel
Para realizar o download da planilha com cálculos de Tempo no Excel clique no botão abaixo e preencha o formulário.