Como usar a função parâmetro do Excel, com exemplos práticos e download da planilha grátis.
Sintaxe Função Parâmetro Excel
A função PARÂMETRO avalia um valor (chamado de expressão) em relação a uma lista de valores e retorna o resultado correspondente ao primeiro valor coincidente. Se não houver nenhuma correspondência, um valor padrão opcional poderá ser retornado.
Em sua forma mais simples a função parâmetro é assim representada:
- =PARÂMETRO(Valor de parâmetro; Valor de correspondência1…[2-126]; Valor para retornar caso haja uma correspondência1…[2-126]; Valor para retornar caso não haja nenhuma correspondência)
Com isso temos uma variável inicial que tem o parâmetro de entrada e para cada valor de referência temos um valor de retorno.
Exemplo da Função
Neste exemplo temos o retorno dos percentuais conforme a região pelo valor parâmetro.
Para a função é disposto no primeiro parâmetro da função a célula D14 aonde, temos a análise se o valor é Norte, retornamos 3,5%, se for Sul, retornamos 5% e assim por diante.
A função que utilizamos foi a seguinte:
=PARÂMETRO(D14;"Norte";0,035;"Sul";0,05;"Leste";0,055;"Nordeste";0,04;"Centro-Oeste";0,045)
Parâmetro com Condições Diferentes do Excel e Valor Aproximado
Neste novo exemplo não é passado um parâmetro variável, passamos o valor VERDADEIRO no lugar do variável.
Além disso temos também o uso do valor aproximado.
A função utilizada é a seguinte:
=PARÂMETRO(VERDADEIRO;D12<HOJE();"Atraso";D12=HOJE();"Vence Hoje";D12>HOJE();"Em aberto")
Com isso temos a verificação se as células D12 estão entre o valor os parâmetros definidos pelos operadores > < e =
Outra forma de realizar esta tarefa é usando a função SES.
=SES(D12<HOJE();"Atraso";D12=HOJE();"Vence Hoje";D12>HOJE();"Em aberto")
Outra forma de fazer isso é com a função PROCX que retorna de forma semelhante os valores aproximados conforme uma tabela.
=PROCX(D12;$B$6:$B$8;Aproximado!$D$6:$D$8;;-1)
Função com Mais Condições
A função Parâmetro permite também que sejam realizados retornos com mais de uma condição para um mesmo parâmetro.
Para isso usamos a seguinte função.
=PARÂMETRO(VERDADEIRO;E(G14<=$C$6;MÁXIMO($C14:$F14)>=$B$6);$D$6;
E(G14<=$C$7;MÁXIMO($C14:$F14)>=$B$7);$D$7;
E(G14<=$C$8;MÁXIMO($C14:$F14)>=$B$8);$D$8;
E(G14<=$C$9;MÁXIMO($C14:$F14)>=$B$9);$D$9;
E(G14<=$C$10;MÁXIMO($C14:$F14)>=$B$10);$D$10;
$D$11)
De forma semelhante pode ser feito com a função SES, aonde temos várias condições usando também a função E para identificar se é verdadeiro o retorno e temos com isso o valor de resultado.
=SES(E(G14<=$C$6;MÁXIMO($C14:$F14)>=$B$6);$D$6;
E(G14<=$C$7;MÁXIMO($C14:$F14)>=$B$7);$D$7;
E(G14<=$C$8;MÁXIMO($C14:$F14)>=$B$8);$D$8;
E(G14<=$C$9;MÁXIMO($C14:$F14)>=$B$9);$D$9;
E(G14<=$C$10;MÁXIMO($C14:$F14)>=$B$10);$D$10;VERDADEIRO;$D$11)
Download Planilha Função Parâmetro Excel
Clique no botão abaixo para realizar o download do arquivo de exemplo:
